Making a helper function for more complex task manipulation

[philj404]

Usually I like the basic timer in(...)/at(...)/every(...) primitive methods. I think they are easy to understand and use correctly.

But... some people might have more complex task creation requirements than these primitives provide. This can be a serious issue if your application has many task instances which each need the same set of startup behaviors -- it would be best to make this shared code rather than trying to maintain copy-pasted code.

Here is an example helper function which has a slightly more complex task startup than the in(...)/at(...)/every(...) primitives can provide.

In this case we want the task to start immediately -- not have an extra delay at startup.

Timer<>::Task timer_now_and_every(unsigned long myInterval, Timer<>::handler_t myTask)
{
    timer.in(0, myTask); // run myTask once on next tick
    return timer.every(myInterval, myTask); // run myTask periodically
}

You could use a helper like this to provide the customized startup behavior on multiple tasks. If you need more customization, just add more input arguments.

Here is a sketch which uses this helper:

// Sketch to demonstrate helper function timer_now_and_every()
//
// It helps timer.every() start its task with no delay
//
#include <arduino-timer.h>

auto timer = timer_create_default();

////////////////////////////////////////////////////////////
Timer<>::Task timer_now_and_every(unsigned long myInterval, Timer<>::handler_t myTask)
{
    timer.in(0, myTask); // run myTask once on next tick
    return timer.every(myInterval, myTask); // run myTask periodically
}
////////////////////////////////////////////////////////////

bool show_elapsed_time(void *) {
  Serial.print(F("Running at: "));
  Serial.print(millis()/1000.);
  Serial.println(F(" seconds."));
  
  return true; // repeat? true
}

void setup() {
  Serial.begin(115200);
  Serial.println(F( "\nRunning " __FILE__ ", Built " __DATE__));

  timer_now_and_every(5000, show_elapsed_time); // show time IMMEDIATELY
}

void loop() {
  timer.tick(); // tick the timer
}